1、在安装脚本的开始处定义 LIBRARY_X64。

!include "MUI.nsh"
!include "Library.nsh"

;如果做32位安装包就把下句注释。
!define LIBRARY_X64

2、注册COM组件，需包含Library.nsh，用宏InstallLib/UnInstallLib 代替RegDLL/UnRegDLL。

;RegDLL "$SYSDIR\ComName.dll"
!insertmacro InstallLib REGDLL NOTSHARED REBOOT_NOTPROTECTED "LocalPath\ComName.dll" "$SYSDIR\ComName.dll" $SYSDIR

;UnRegDLL "$SYSDIR\ComName.dll"
!insertmacro UnInstallLib REGDLL NOTSHARED REBOOT_NOTPROTECTED "$SYSDIR\ComName.dll"

3、在调用涉及注册表的函数前用 SetRegView 64，后用 SetRegView lastused。

!ifdef  LIBRARY_X64
 SetRegView 64
!endif

 WriteRegStr ...
 WriteRegStr ...
 WriteRegStr ...

!ifdef  LIBRARY_X64
 SetRegView lastused
!endif 

SetRegView用户手册：
在 Windows x64 上共有2种查看方式。一种用于 32-bit 应用程序，另一种用于 x64 应用程序。默认情况下，32-bit 应用程序运行在 x64 系统的 WOW64 模式下时，只允许使用 32-bit 查看方式。使用 SetRegView 64 将允许安装程序在 x64 中访问注册表键值。

它将影响
DeleteRegKey,
DeleteRegValue,
EnumRegKey,
EnumRegValue,
ReadRegDWORD,
ReadRegStr,
WriteRegBin,
WriteRegDWORD,
WriteRegStr,
WriteRegExpandStr。

它不会影响 InstallDirRegKey。另外，在函数 .onInit 中也可使用 ReadRegStr 读取注册表。

SetRegView 32
ReadRegStr $0 HKLM Software\Microsoft\Windows\CurrentVersion ProgramFilesDir
DetailPrint $0 # prints C:\Program Files (x86)
SetRegView 64
ReadRegStr $0 HKLM Software\Microsoft\Windows\CurrentVersion ProgramFilesDir
DetailPrint $0 # prints C:\Program Files

Function .onInit
  SetRegView 64
  ReadRegStr $INSTDIR HKLM Software\NSIS ""
  SetRegView 32
FunctionEnd

4、在调用涉及目标机器上系统目录（即$SYSDIR）的函数前用 ${DisableX64FSRedirection}。

在安装包的第一个Section中调用一次即可。
!ifdef  LIBRARY_X64
 ${DisableX64FSRedirection}
!endif 

5、在64位系统上 $PROGRAMFILES64 表示“Program Files”, $PROGRAMFILES 表示 “Program Files (x86)”。

可以在安装脚本的开始处定义一个常量，
!ifdef LIBRARY_X64
!define PROGRAM_FILES_MAP  $PROGRAMFILES64
!else
!define PROGRAM_FILES_MAP  $PROGRAMFILES
!endif
以后直接用 ${PROGRAM_FILES_MAP} 代替 $PROGRAMFILES。

6、在.onInit 和 un.onInit 中判断一下，如果安装包是在32位操作系统上运行，则停止安装。

可创建一个宏，然后在需要的地方插入。
!macro TIP_WHEN_AMD64_INSTALLER_RUNAT_X86
 !ifdef LIBRARY_X64
  ${If} ${RunningX64}
  ${else}
     MessageBox MB_OK|MB_ICONINFORMATION "请在64位操作系统下运行。"
   Abort
  ${EndIf}
 !endif
!macroend

Function .onInit
 !insertmacro TIP_WHEN_AMD64_INSTALLER_RUNAT_X86
 SetShellVarContext all  ;安装到所有用户下，current 表示安装到当前用户下, all 表示所有用户下。
FunctionEnd

Function un.onInit
 !insertmacro TIP_WHEN_AMD64_INSTALLER_RUNAT_X86
 SetShellVarContext all
FunctionEnd

备注：
1、在 NSIS 中的条件编译是 !开头，不是 #开头，如!ifdef。
2、对COM组件，我认为应该是使用 NOTSHARED 方式注册。
3、可以做个批处理文件，一次性生成32位/64位的安装包。
 如 x.bat
 rem "记得要把安装脚本中的 !define LIBRARY_X64 注释掉，否则不能生成32位安装包。"
 makensis .\myinstaller.nsi
 makensis /DLIBRARY_X64 .\myinstaller.nsi
 pause