C++博客-newplan-随笔分类-IBM-PC 汇编 Programming Notes && Keys

CPP内嵌汇编代码

山泉弯延 — Sat, 10 May 2008 09:54:00 GMT

win32:DEV C++ 格式：
  #include <iostream>
  using namespace std;


        int a=1;/*a,b 应当都是全局的*/
        int b=10;

  int main(int argc,char **argv)
  {
         cout<<sizeof(int)<<endl;

         /*AT&T 规范 Not Intel*/
         __asm("mov _b,%eax");//mov 的左边是源，右边是目标

         __asm("mov %eax,_a");

         cout<<a<<endl;

         cout<<b<<endl;

         cout<<"a+b="<<a+b<<endl;

         getchar();

         return(a-b);
  }
win32:VC6.0格式:
#include <iostream>
using namespace std;
int main(int argc,char **argv)
{
        /*int的长度和eax的长度一样都是4个字节*/
        cout<<sizeof(int)<<endl;
        int a=100;
        int b=10;
        /*Intel 规范*/
         __asm{
          mov eax,a;//eax 是目标，a 是源
          add eax,b;
          mov a,eax;
              }
         cout<<a<<endl;
         cout<<"a+b="<<a<<endl;
         return(a-b);
}

山泉弯延 2008-05-10 17:54 发表评论

汇编键盘中断演示左右shift

山泉弯延 — Thu, 03 Jan 2008 16:12:00 GMT

stack   segment para    stack   'stack'
        db      256     dup(0)
stack   ends
;
data    segment    para    public    'data'
buffer    db    16h dup(0)
bufpt1    dw    0
bufpt2    dw    0
kbflag    db    0

prompt    db    '---kbd_io program begin ---',13,10,'$'
scantab    db    0,0,'1234567890-=',0,0
    db    'qwertyuiop[]',0dh,0
    db    'asdfghjkl;',0,0,0,0
    db    'zxcvbnm,./',0,0,0
    db    ' ',0,0,0,0,0,0,0,0,0,0,0,0,0
    db    '789-456+1230.'
even
shiftab    db    0,0,'!@#$%^&*()_+',0,0
    db    'QWERTYUIOP{}',0dh,0
    db    'ASDFGHJKL:"',0,0,0
    db    'ZXCVBNM<>?',0,0,0
    db    ' ',26 dup(0)
even
oldcs9    dw    ?
oldip9    dw    ?
data    ends
;
code    segment    para    public    'code'
start    proc    far
    assume    cs:code,ds:data
    push    ds
    mov    ax,0
    push    ax
    mov    ax,data
    mov    ds,ax

    cli
    mov    al,09
    mov    ah,35h
     int    21h
    mov    oldcs9,es
    mov    oldip9,bx         ;保存中断

    push    ds
    mov    dx,offset kbint
    mov    ax,seg    kbint
    mov    ds,ax
    mov    al,09
    mov    ah,25h
    int    21h
    pop    ds                ;设置中断

    in    al,21h
    and     al,0fdh
    out    21h,al

        mov     dx,offset prompt
    mov    ah,09
    int     21h
    sti
forever:
    call    kbget
    test    kbflag,80h
    jnz    endint
    push    ax
    call    dispchar
    pop    ax
    cmp    al,0dh
    jnz    forever
    mov    al,0ah
    call    dispchar
    jmp    forever
endint:
    mov    dx,oldip9
    mov    ax,oldcs9
    mov    ds,ax
    mov    al,09h
    mov    ah,25h
    int    21h

    ret
start    endp
kbget    proc    near
    push    bx
    cli
    mov    bx,bufpt1
    cmp    bx,bufpt2
    jnz     kbget2
    cmp    kbflag,80h
    jz    kbget3
    sti
    pop    bx
    jmp    kbget
kbget2:
    mov    al,[buffer+bx]
    inc    bx
    cmp    bx,16
    jc    kbget3
    mov    bx,0
kbget3:
    mov    bufpt1,bx
    pop    bx
    ret
kbget    endp
;------------------------------------------------------------
kbint    proc     far
    push    bx
    push    ax
;
    in    al,60h
    push    ax
    in    al,61h
    or    al,80h
    out     61h,al
    and    al,7fh
    out    61h,al
;
    pop    ax
    test    al,80h
    jnz    kbint5
        cmp     al,42
         jz     left_shif
        cmp     al,54
         jz     right_shif
        test    kbflag,03h    ;判断shif键是否按住
        jnz     press_shif
        mov     bx,offset scantab
    xlat    scantab
    cmp    al,0
    jnz    kbint4
    mov    kbflag,80h
    jmp    kbint2

left_shif:
        or    kbflag,01h
        jmp   kbint2
right_shif:
        or    kbflag,02h
        jmp   kbint2

press_shif:
            mov     bx,offset shiftab
        xlat    shiftab
        cmp        al,0
        jnz        kbint4
        mov        kbflag,80h
        jmp        kbint2

kbint4:
    mov    bx,bufpt2
    mov    [buffer+bx],al
    inc     bx
    cmp    bx,16
    jc    kbint3
    mov    bx,0
kbint3:
    cmp    bx,bufpt1
    jz    kbint2
    mov    bufpt2,bx
kbint5:
        cmp     al,0aah
    jz    kbint1
    cmp    al,0b6h
    jz    kbint1
    jmp    kbint2
kbint1: mov     kbflag,0
kbint2:
    cli
    mov    al,20h
    out    20h,al
    pop    ax
    pop    bx
    sti
    iret
kbint    endp
;
dispchar    proc    near
    push    bx
    mov    bx,0
    mov    ah,0eh
    int    10h
    pop    bx
    ret
dispchar    endp
;
code    ends
    end    start

山泉弯延 2008-01-04 00:12 发表评论

汇编实现查找电话号码

山泉弯延 — Fri, 07 Dec 2007 11:22:00 GMT

;**********************电话号码表实现*******************************

;在本次试验中需要注意基址寄存器BX的移动方法，对以字为单位的数组，BX的移动方式
;是每移动一次加2或者减2
;另外函数调用的过程中需要小心PUSH和pop的调用是否安全，例如在name_sort中pop CX的
;时候没有先Push CX，导致了name_sort函数不可以调用
;此程序使用比较高效的方法只是对号码单的首地址进行排序，为此开辟了一个地址数组
;AdTable，类似C语言中的指针数组
;在每个名字的前面存有每个名字的长度，有利于对名字进行比较，体现了空间换时间
;程序调试难度较大，费时2天长度，长度349行
;12月7日于海韵
;==================================================================
DateArea    segment
     TemplateName        db 20,?,20 dup(?)

     TemplateNumber      db 9,?,9 dup(?)

     PhoneTable          db 50 dup ( 21 dup (?), 8 dup (?) ,'$')

     AdTable             dw 50 dup (?)

     FindedAdress        dw 1 dup (?)

     InputNamePrint      db 13,10,'Input name:','$'

     InputNumPrint       db 13,10,'Input a telephone number:','$'

     AskForNumPrint      db 13,10,'Do you want a telepment numbre:(Y/N)','$'

     NamePrint           db 13,10,'name?','$'

     AnswerFindedPrint   db  13,10,'name',16 dup (20h),'tel.',13,10,'$'

     AnswerNoFindPrint   db  13,10,'NO SUCH NAME!','$'
DateArea ends
;=====================================================================
CodeArea  segment
      assume cs:CodeArea ,ds:DateArea ,es:DateArea
;-----------------------------
main proc far

      push ds
      sub ax,ax
      push ax
      mov ax,DateArea
      mov ds,ax
      mov es,ax
      ;
      mov bx,0
      lea si,PhoneTable

Start:

      lea dx , InputNamePrint
      mov ah,09h
      int 21h
      ;
       lea  di,AdTable
       mov  AdTable[bx],si
       call input_name;该函数还要返回输入字母为终止时候的提示,
      ;可以返回一个寄存器的状态来表示
       jz Search
       call stor_name
      ;
       lea dx, InputNumPrint
       mov ah ,09h
       int 21h
      ;
       call inphone
      ;
       add si,30
       add bx ,2
       jmp Start

Search:
       ;lea dx, AskForNumPrint
       ;mov ah,09h
       ;int  21h
       call name_sort
       lea dx, AskForNumPrint
       mov ah,09h
       int  21h
       ;
       mov ah,1
       int 21h
       sub al,4Eh
       ;
       jz  Exit
       ;
       lea  dx,NamePrint
       mov ah,09h
       int 21h
       ;
       call input_name
       ;
       call name_search
       ;
       call printline
       ;
       jmp Search

Exit:  ret
main endp
;------------------------------
input_name proc near
   push ax
   push bx
   push cx
   push dx
   push si
   push di
   ;
   lea  dx,TemplateName
   mov  ah,0ah
   int  21h
   lea  di ,TemplateName
   add  di,1
   mov al,[di]
   cmp al,0
   ;
   pop di
   pop si
   pop dx
   pop cx
   pop bx
   pop ax

   ;
   ret
input_name endp
;------------------------------
stor_name  proc near
   push ax
   push bx
   push cx
   push dx
   push si
   push di
   ;
   mov  di,AdTable[bx]
   lea  si,TemplateName
   add  si,1
   mov  dx,21
   mov  cl,[si]
   mov  al,cl
   cbw
   mov  cx,ax
   inc  cx
   sub  dx,cx
   cld
   repnz movsb
   mov  cx,dx
   cld
   mov al ,20h
   repnz stosb
   ;
   pop di
   pop si
   pop dx
   pop cx
   pop bx
   pop ax
   ;
ret
;
stor_name  endp
;------------------------------
inphone proc near
  push ax
  push bx
  push cx
  push dx
  push si
  push di
  ;
  lea dx,TemplateNumber
  mov  ah,0ah
  int  21h
  ;
  mov di,AdTable[bx]
  add di,21
  lea si,TemplateNumber
  add si,1
  mov cl,[si]
  mov al,cl
  cbw
  mov cx,ax
  add si,1
  cld
  repnz movsb
  ;
  pop di
  pop si
  pop dx
  pop cx
  pop bx
  pop ax
  ;
ret
inphone endp
;------------------------------
name_sort proc near
    push ax
    push bx
    push cx
    push dx
    push si
    push di
    lea  dx, AskForNumPrint
    mov  ah,09h
    int  21h
    mov cx,bx
OuterSort:
    mov bx,0
InnerSort:
    mov si,AdTable[bx]
    add bx,2
    mov di ,AdTable[bx]
    mov al,[si]
    mov dl,[di]
    cmp al,dl
    push cx
    jg  AxGrBx

    mov al,dl
    cbw
    mov cx,ax
    jmp PassAGB
AxGrBx:
    cbw
    mov cx,ax
PassAGB:
    add si ,1
    add di ,1
    cld

    repz  cmpsb
    pop    cx
    jb     Belower
    mov    ax,AdTable[bx]
    sub    bx,2
    mov    dx,AdTable[bx]
    xchg   ax,dx
    mov  AdTable[bx],dx
    add    bx,2
    mov  AdTable[bx],ax
Belower:
    mov   ax,bx
    add   ax,2
    cmp   ax,cx
    jnz  InnerSort
    sub cx,2
    cmp cx,2
jnz OuterSort
    pop di
    pop si
    pop dx
    pop cx
    pop bx
    pop ax
ret
name_sort endp
;------------------------------
name_search proc near
    push ax
    push bx
    push cx
    push dx
    push si
    push di
    mov ax,bx
    mov bx ,0
mLoop:
    lea si,TemplateName+1
    mov cl,[si]
    push ax
    mov al,cl
    cbw
    mov cx,ax
    add cx,1
    pop ax
    mov di,AdTable[bx]
    cld
    repz cmpsb
    jz  FindOutNum
    add bx, 2
    cmp bx ,ax
    jz  FindNoNum
    jmp mLoop
FindNoNum:
    pop  di
    pop  si
    pop  dx
    pop  cx
    pop  bx
    pop  ax
    ret
FindOutNum:
    mov dx,AdTable[bx]
    add dx,1
    mov FindedAdress,dx
    ;mov ah,09h
   ; int 21h
    pop di
    pop si
    pop dx
    pop cx
    pop bx
    pop ax
    ret
name_search endp
;------------------------------
printline  proc near
    push ax
    push bx
    push cx
    push dx
    push si
    push di
    jz NoFind
    lea dx,AnswerFindedPrint
    mov ah,09
    int 21h
    mov dx,[FindedAdress]
    mov ah,09h
    int 21h
    JMP RetPlace
NoFind:
    lea dx,AnswerNoFindPrint
    mov ah,09h
    int 21h
RetPlace:
    pop di
    pop si
    pop dx
    pop cx
    pop bx
    pop ax

    ret
printline endp
;------------------------------

CodeArea ends
end main

山泉弯延 2007-12-07 19:22 发表评论

汇编查找程序简单实现

山泉弯延 — Thu, 22 Nov 2007 15:01:00 GMT

摘要: 07年11月22日于海韵阅读全文

山泉弯延 2007-11-22 23:01 发表评论

简单的汇编排序输出程序

山泉弯延 — Mon, 05 Nov 2007 13:56:00 GMT

摘要: 为什么使用STOS给printn串存入单个字总是难以实现？阅读全文

山泉弯延 2007-11-05 21:56 发表评论