C++博客-O型饭桶-随笔分类-Win32Asm

给Windows的记事本添加上下翻页功能(1)[原创]

O型饭桶 — Tue, 21 Apr 2009 14:03:00 GMT

出于无聊和记事本确实不怎么好用的目的，所以准备给记事本添加上下翻页的功能。

首先要做的事情就是修改程序入口点，这样一来才能优先获取程序的控制权，废话就不多说了。

1. 想要修改程序的入口点首先就要观察下程序员先的入口点在什么位置，这样一来等我们的处理完毕后还是要把控制权还给记事本，以免出现错误。

用LoadPE看看记事本的一些信息

从这里可以很清楚的发现磁盘文件入口在400偏移处而文件对齐是7800字节大小，实际使用的是7748字节大小，那么也就是说7800-7748=b8h空间可以供我们插入代码

2. 知道了即将插入代码的地方，那么就准备好机器码以便处理，这里我们先只修改程序入口，其余的操作以后再写。

从这里我们可以看到程序原先的入口偏移地址在739dh处，也就是说我们做完自己的处理后要跳转到这里。

B8 9D 73 00 01 ff E0

这便是

mov eax, 0100739dh

jmp eax

的机器码

3. 修改文件入口

因为文件偏移地址为400h而实际使用的字节数为7748h那么也就是说我们要在 7b49h处插入我们的代码。(再声明一次，时间有限今天只能写修改入口，至于其他操作，后面有时间的时候再继续写)

用UE打开notepade.exe，在空隙处插入我们新的入口代码

4. 修改程序入口点

因为原先的代码段偏移地址为1000h，而实际.text节大小为7748那么也就是说新的程序入口应该是7748h+1000h=8749h

修改完毕后点击Sava。

再次运行notepad.exe

没有任何异常，那么修改程序入口成功。

当然你可能认为什么都还么做呢。呵呵，入口控制权被拿到了，那么接下来就可以自由发挥了。

时间有限，下次将在今天修改的入口点给notepad.exe载入我们的dll文件，紧接着，用我们的dlll来处理记事本的翻页功能待续…

O型饭桶 2009-04-21 22:03 发表评论

俄罗斯方块雏形[完成了移动、反转、叠加][原创]

O型饭桶 — Tue, 21 Apr 2009 01:28:00 GMT

>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
; 俄罗斯方块 by Originality
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
.386
.model flat, stdcall
option casemap : none
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
; Include 文件定义
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
include rgame.inc
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
; 代码段
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
    .code
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
; 定时器测试
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
DwonTest proc _hWnd, _uMsg, _idEvent, _dwTime

    pushad

    mov    eax, curState
    .if    eax        ;下落结束

        mov    curState, 0
        invoke    InitControl1

    .else

        invoke    Control1Down

    .endif

    popad
    ret

DwonTest endp
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
; 窗口过程
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
_ProcWinMain proc uses ebx edi esi hWnd, uMsg, wParam, lParam
    local    @stPs : PAINTSTRUCT
    local    @stRect : RECT
    local    @hDc

    mov    eax, uMsg
;********************************************************************
    .if    eax == WM_PAINT

        invoke    BeginPaint, hWnd, addr @stPs
        invoke    InitContainer
        invoke    ShowControl, 1
        invoke    Control1Down
        invoke     EndPaint, hWnd, addr @stPs

    .elseif    eax == WM_CREATE

        invoke    GetDC, hWnd
        mov    hGame, eax
        ;【此处定时器为测试所用】
        invoke    SetTimer, NULL, NULL, 1000, offset DwonTest

    .elseif    eax == WM_CLOSE

        invoke    ReleaseDC, hWnd, hGame
        invoke     DestroyWindow, hWinMain
        invoke     PostQuitMessage, NULL

    .elseif    eax == WM_SIZE

        invoke    ValidateRect, hWnd, offset gameArea

    .else

        invoke     DefWindowProc, hWnd, uMsg, wParam, lParam
        ret

    .endif
;********************************************************************
        xor    eax, eax
        ret

_ProcWinMain endp
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
_WinMain proc
    local    @stWndClass : WNDCLASSEX
    local    @stMsg : MSG

    invoke     GetModuleHandle, NULL            ;获得应用程序实例
    mov    hInstance, eax                ;实例保存在全局变量中
    invoke     RtlZeroMemory, addr @stWndClass, sizeof @stWndClass    ;以0填充WNDCLASSEX结构体

********************************************************************
; 注册窗口类
;********************************************************************
    invoke     LoadCursor, 0, IDC_ARROW            ;获取光标句柄
    mov    @stWndClass.hCursor, eax            ;设置光标
    push    hInstance
    pop    @stWndClass.hInstance            ;保存应用程序实例
    mov    @stWndClass.cbSize, sizeof WNDCLASSEX    ;保存结构体大小
    mov    @stWndClass.style, CS_HREDRAW or CS_VREDRAW    ;设置窗体样式
    mov    @stWndClass.lpfnWndProc, offset _ProcWinMain    ;保存回调函数
    mov    @stWndClass.hbrBackground, COLOR_WINDOW + 3    ;设置窗体背景色
    mov    @stWndClass.lpszClassName, offset szClassName    ;保存窗体类名
    invoke     RegisterClassEx, addr @stWndClass        ;注册窗口类
;********************************************************************
; 建立并显示窗口
;********************************************************************
    invoke     CreateWindowEx, WS_EX_TOOLWINDOW, offset szClassName, offset szCaptionMain,\
                   WS_OVERLAPPEDWINDOW,\
                   100, 100, 400, 456,\
                   NULL, NULL, hInstance, NULL            ;建立窗口
    mov    hWinMain, eax                    ;保存窗口句柄
    invoke     ShowWindow, hWinMain, SW_SHOWNORMAL        ;显示窗口
    invoke     UpdateWindow, hWinMain                ;更新窗口
;********************************************************************
; 消息循环
;********************************************************************
    .while    TRUE                        ;消息循环

        invoke     GetMessage, addr @stMsg, NULL, 0, 0        ;获取消息并填充MSG结构体

            .break .if    eax == 0                ;判断是否退出
            invoke     TranslateMessage, addr @stMsg        ;消息装换
            invoke     DispatchMessage, addr @stMsg        ;分发消息

        .endw
        ret

_WinMain endp

;********************************************************************
; 初始化游戏容器
;********************************************************************
InitContainer proc
    local @lpRect : RECT

    pushad

    ;建立游戏容器边框
    invoke    CreatePen, PS_SOLID, 5, 8000FFh
    push    eax
    invoke    SelectObject, hGame, eax
    invoke    DeleteObject, eax
    pop    eax
    invoke    FrameRect, hGame, offset gameArea, eax

    popad
    ret

InitContainer endp

;********************************************************************
; 显示方块控件
; type：控件类型1为4格横条，2为田字形，3..4..
;********************************************************************
ShowControl proc cType : DWORD

    pushad

    .if    cType == 1    ;4格横条■■■■

        invoke    InitControl1

    .endif

    popad
    ret

ShowControl endp

;********************************************************************
; 初始化■■■■图形
;********************************************************************
InitControl1 proc

    pushad

    ;设置方块颜色
    invoke    SetColor, 0FF80FFh, 400040h
    ;创建方块并排列方块
    mov    ecx, 60        ;左上角起始位置
    mov    edx, 90        ;右下角起始位置
    xor    esi, esi
    lea    ebx, curControl
@@:
    cmp    ecx, 180
    jz    @F        ;4个方块都初始化完毕
    push    ebx
    push    ecx
    push    edx
    invoke    Rectangle, hGame, ecx, 5, edx, 30
    pop    edx
    pop    ecx
    pop    ebx
    mov    [ebx + esi], ecx
    push    topSpace
    pop    DWORD ptr [ebx + esi + 4]
    add    esi, 8
    add    ecx, 30
    add    edx, 30
    jmp    @B

@@:

    popad
    ret

InitControl1 endp

;********************************************************************
; 设置方块颜色
;********************************************************************
SetColor proc color : DWORD, pColor : DWORD

    pushad

    invoke    CreatePen, PS_SOLID, 1, pColor
    invoke    SelectObject, hGame, eax
    invoke    DeleteObject, eax
    invoke    CreateSolidBrush, color
    invoke    SelectObject, hGame, eax
    invoke    DeleteObject, eax

    popad
    ret

SetColor endp

;********************************************************************
; ■■■■图形向下走动
;********************************************************************
Control1Down proc

    pushad

    invoke    IsDownEnd
    .if     eax == 1    ;下面有障碍，改变状态为创建新的方块并保存当前方块在容器中的位置

        mov    curState, 1
        invoke    ChangeAreaState
        invoke    RtlZeroMemory, offset curControl, sizeof curControl
        popad
        ret

    .endif

    ;如果下面不是障碍，则■■■■向下走动
    lea    edx, curControl
    xor    ecx, ecx
@@:
    cmp    ecx, 4
    jz    @F
    ;覆盖原有的方块
    push    ecx
    invoke    SetColor, 0h, 0h
    mov    eax, [edx + ecx * 8 + 4]
    mov    ebx, 30
    add    ebx, eax    ;ebx右下角y坐标
    mov    eax, [edx + ecx * 8]
    add    eax, 30        ;eax为右下角x坐标
    push    eax        ;保存右下角坐标
    push    ebx
    push    edx
    invoke    Rectangle, hGame, [edx + ecx * 8], [edx + ecx * 8 + 4], eax, ebx
    pop    edx

    ;生成新的方块
    invoke    SetColor, 0FF80FFh, 400040h
    pop    ebx
    pop    eax
    pop    ecx
    add     DWORD ptr [edx + ecx * 8 + 4], 30
    add    ebx, 30
    push    ecx
    push    edx
    invoke    Rectangle, hGame, [edx + ecx * 8], [edx + ecx * 8 + 4], eax, ebx
    pop    edx
    pop    ecx
    inc    ecx
    jmp    @B
@@:

    popad
    ret

Control1Down endp

;********************************************************************
; 保存当前方块在容器中的状态
;********************************************************************
ChangeAreaState proc

    pushad

    ;计算区域单元坐标
    lea    ebx, curControl
    xor    ecx, ecx
@@:
    cmp    ecx, 4
    jz    @F

    ;计算二维x坐标
    invoke    CalculatePos, [ebx + ecx * 8 ], [ebx + ecx * 8 + 4], 1
    mov    esi, eax

    ;计算二维y坐标
    invoke    CalculatePos, [ebx + ecx * 8 ], [ebx + ecx * 8 + 4], 2
    mov    edi, eax

    ;设置区域更新，更新的坐标位置（eax + esi * 4 * 8 + edi * 4）
    lea    eax, area
    push    eax
    xchg    edi, eax
    mov    edi, 8
    mul    edi
    add    esi, eax
    pop    eax
    mov    DWORD ptr [eax + esi * 4], 1    ;设置当前位置已经被填充
    inc    ecx
    jmp    @B
@@:

    popad
    ret

ChangeAreaState endp

;********************************************************************
; 根据顶角计算二维坐标
; left, top：顶角像素
; posType：1表示计算x坐标，2表示计算y坐标
; eax返回二维坐标
;********************************************************************
CalculatePos proc left : DWORD, top :DWORD, posType : DWORD
    local @ret : DWORD
    pushad

    mov    edx, left
    add    edx, rectArea ;右下角x坐标

    mov    ecx, top
    add    ecx, rectArea ;右下角y坐标

    .if    posType == 1

        mov    eax, edx
        mov    ebx, 30
        xor    edx, edx
        div    ebx

    .elseif

        mov    eax, ecx
        sub    eax, topSpace
        mov    ecx, 30
        xor    edx, edx
        div    ecx

    .endif
    mov    @ret, eax
    popad
    mov    eax, @ret
    dec    eax
    ret

CalculatePos endp

;********************************************************************
; 判断下面是否有障碍
; 返回值:：eax为1表示下落完毕，为0表示未完毕
;********************************************************************
IsDownEnd proc

    pushad

    lea    ebx, curControl
    xor    ecx, ecx
@@:
    cmp    ecx, 4
    jz    @F

    ;计算二维x坐标
    invoke    CalculatePos, [ebx + ecx * 8 ], [ebx + ecx * 8 + 4], 1
    mov    esi, eax

    ;计算二维y坐标
    invoke    CalculatePos, [ebx + ecx * 8 ], [ebx + ecx * 8 + 4], 2
    mov    edi, eax
    inc    edi

    ;设置区域更新，更新的坐标位置（eax + esi * 4 * 8 + edi * 4）
    lea    eax, area
    push    eax
    xchg    edi, eax
    mov    edi, 8
    mul    edi
    add    esi, eax
    pop    eax
    mov    edx, [eax + esi * 4]
    .if    edx == 1

        popad
        mov    eax, 1
        ret

    .endif
    inc    ecx
    jmp    @B
@@:

    popad
    xor    eax, eax
    ret

IsDownEnd endp
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
start:
    call    _WinMain
    invoke     ExitProcess, NULL
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
end start

O型饭桶 2009-04-21 09:28 发表评论

简单keygen制作[原创]

O型饭桶 — Mon, 20 Apr 2009 14:17:00 GMT

举个简单的例子说明下，以下就是软件的注册码关键代码，根据其生成注册码的函数，分析其思路，写出相应的程序生成注册码即可。

004011AE . 6A 51 PUSH 51 ; /Count = 51 (81.)
004011B0 . 50 PUSH EAX ; |Buffer
004011B1 . 6A 6E PUSH 6E ; |ControlID = 6E (110.)
004011B3 . 56 PUSH ESI ; |hWnd
004011B4 . FFD7 CALL EDI ; \GetDlgItemTextA
004011B6 . 8D8C24 9C0000>LEA ECX,DWORD PTR SS:[ESP+9C]
004011BD . 6A 65 PUSH 65 ; /Count = 65 (101.)
004011BF . 51 PUSH ECX ; |Buffer
004011C0 . 68 E8030000 PUSH 3E8 ; |ControlID = 3E8 (1000.)
004011C5 . 56 PUSH ESI ; |hWnd
004011C6 . 8BD8 MOV EBX,EAX ; |EBX存放用户名的长度
004011C8 . FFD7 CALL EDI ; \GetDlgItemTextA
004011CA . 8A4424 4C MOV AL,BYTE PTR SS:[ESP+4C]
004011CE . 84C0 TEST AL,AL ; 是否结束
004011D0 . 74 76 JE SHORT TraceMe.00401248
004011D2 . 83FB 05 CMP EBX,5
004011D5 . 7C 71 JL SHORT TraceMe.00401248 ; 如果用户名长度小于5，跳
004011D7 . 8D5424 4C LEA EDX,DWORD PTR SS:[ESP+4C] ; EDX指向用户名
004011DB . 53 PUSH EBX ; 用户名长度
004011DC . 8D8424 A00000>LEA EAX,DWORD PTR SS:[ESP+A0]
004011E3 . 52 PUSH EDX ; 用户名
004011E4 . 50 PUSH EAX ; key
004011E5 . E8 56010000 CALL TraceMe.00401340 ; 判断注册码是否正确，有三个参数[输入key，用户名，用户名长度]

思路：
从用户名的第4个字符开始分别与全局的一个长度为7的标识相乘最后和就为key
--注册码部分--
00401340 /$ 55 PUSH EBP ; 保存EBP
00401341 |. 8B6C24 0C MOV EBP,DWORD PTR SS:[ESP+C] ; 获取第2个参数，用户名
00401345 |. 56 PUSH ESI ; 保护ESI,EDI
00401346 |. 57 PUSH EDI
00401347 |. 8B7C24 18 MOV EDI,DWORD PTR SS:[ESP+18] ; 取第一个参数，用户名长度
0040134B |. B9 03000000 MOV ECX,3
00401350 |. 33F6 XOR ESI,ESI
00401352 |. 33C0 XOR EAX,EAX
00401354 |. 3BF9 CMP EDI,ECX
00401356 |. 7E 21 JLE SHORT TraceMe.00401379 ; 如果用户名长度小于等于3，跳
00401358 |. 53 PUSH EBX
00401359 |> 83F8 07 /CMP EAX,7
0040135C |. 7E 02 |JLE SHORT TraceMe.00401360 ; 如果EAX小于等于7，跳
0040135E |. 33C0 |XOR EAX,EAX
00401360 |> 33D2 |XOR EDX,EDX
00401362 |. 33DB |XOR EBX,EBX
00401364 |. 8A1429 |MOV DL,BYTE PTR DS:[ECX+EBP] ; DL存放从用户名中取出的第ECX字符
00401367 |. 8A98 30504000 |MOV BL,BYTE PTR DS:[EAX+405030] ; BL存放某个全局变量
0040136D |. 0FAFD3 |IMUL EDX,EBX ; 某个用户名×全局变量C
00401370 |. 03F2 |ADD ESI,EDX ; ESI似乎是这些值的统计
00401372 |. 41 |INC ECX
00401373 |. 40 |INC EAX
00401374 |. 3BCF |CMP ECX,EDI ; 如果ECX小于用户名的长度则继续循环
00401376 |.^ 7C E1 \JL SHORT TraceMe.00401359
00401378 |. 5B POP EBX ; 还原EBX，不需要使用了
00401379 |> 56 PUSH ESI ; /<%ld>
0040137A |. 68 78504000 PUSH TraceMe.00405078 ; |Format = "%ld"
0040137F |. 55 PUSH EBP ; |s
00401380 |. FF15 9C404000 CALL DWORD PTR DS:[<&USER32.wsprintfA>] ; \wsprintfA
00401386 |. 8B4424 1C MOV EAX,DWORD PTR SS:[ESP+1C]
0040138A |. 83C4 0C ADD ESP,0C ; C调用方式
0040138D |. 55 PUSH EBP ; /String2
0040138E |. 50 PUSH EAX ; |String1
0040138F |. FF15 04404000 CALL DWORD PTR DS:[<&KERNEL32.lstrcmpA>] ; \lstrcmpA
00401395 |. F7D8 NEG EAX
00401397 |. 1BC0 SBB EAX,EAX
00401399 |. 5F POP EDI
0040139A |. 5E POP ESI
0040139B |. 40 INC EAX
0040139C |. 5D POP EBP
0040139D \. C3 RETN

private string GetKey(string userName, int userNameLength)
{
int ecx = 3;
int sum = 0;
int eax = 0;
int[] flag = {0x0C, 0x0A, 0x13, 0x09, 0x0C, 0x0B, 0x0A, 0x08};
while (ecx < userNameLength)
{
if (eax >= flag.Length)
eax = eax % flag.Length;
sum += userName[ecx] * flag[eax];
ecx++;
eax++;
}
return sum.ToString();
}

O型饭桶 2009-04-20 22:17 发表评论

MFC42.#823函数到底有什么作用[原创]

O型饭桶 — Mon, 20 Apr 2009 14:15:00 GMT

由于多次跟踪程序的时候碰到了，一直没怎么理会，今天出于好奇，进去逛了下。。。很简单，原来就是分配内存。

注释写的很清楚，而且很简单，所以不多做解释了。

6E26152C > 8BFF         MOV EDI,EDI
6E26152E    55              PUSH EBP
6E26152F    8BEC          MOV EBP,ESP
6E261531    53              PUSH EBX
6E261532    8B5D 08     MOV EBX,DWORD PTR SS:[EBP+8]                               ; EBX为第一个参数
6E261535    56              PUSH ESI
6E261536    57              PUSH EDI
6E261537    53              PUSH EBX
6E261538    83CF FF      OR EDI,FFFFFFFF                                            ; EDI=-1
6E26153B    FF15 6C10256E   CALL DWORD PTR DS:[<&msvcrt.malloc>]                       ; msvcrt.malloc
6E261541    8BF0          MOV ESI,EAX                                                ; ESI保存内存指针
6E261543    83C4 04     ADD ESP,4                                                  ; 堆栈平衡
6E261546    85F6          TEST ESI,ESI                                               ; 判断分配是否成功
6E261548    0F84 9E1E0000   JE MFC42.6E2633EC                                          ; 如果分配失败则跳转
6E26154E    5F              POP EDI                                                    ; 从这里可以看出6E261537H地址处的PUSH为传参而不是寄存器保护
6E26154F    8BC6          MOV EAX,ESI                                                ; 到了这里也就知道了MFC42.#823号函数主要就是分配内存的作用
6E261551    5E              POP ESI
6E261552    5B              POP EBX
6E261553    5D              POP EBP
6E261554    C3              RETN

O型饭桶 2009-04-20 22:15 发表评论